plugins { id 'com.android.application' }

def signing = new Properties()
def signingFile = rootProject.file('.private/signing.properties')
if (signingFile.exists()) signingFile.withInputStream { signing.load(it) }

android {
    namespace 'ru.kusoft.qsafe'
    compileSdk 35
    defaultConfig {
        applicationId 'ru.kusoft.qsafe'
        minSdk 28
        targetSdk 35
        versionCode = (project.findProperty('qsafeVersionCode') ?: '8').toInteger()
        versionName = (project.findProperty('qsafeVersionName') ?: '1.1.0')
        testInstrumentationRunner 'ru.kusoft.qsafe.QSafeTestRunner'
    }
    signingConfigs {
        release {
            if (signingFile.exists()) {
                storeFile rootProject.file(signing.getProperty('storeFile'))
                storePassword signing.getProperty('storePassword')
                keyAlias signing.getProperty('keyAlias')
                keyPassword signing.getProperty('keyPassword')
            }
        }
    }
    buildTypes { release { signingConfig signingConfigs.release; minifyEnabled false } }
    compileOptions { sourceCompatibility JavaVersion.VERSION_17; targetCompatibility JavaVersion.VERSION_17 }
    buildFeatures { buildConfig true }
    sourceSets { main.resources.srcDir rootProject.file('shared') }
    testOptions { unitTests.returnDefaultValues = true }
    lint { abortOnError true }
}

dependencies {
    androidTestImplementation 'androidx.test:runner:1.6.2'
    testImplementation 'junit:junit:4.13.2'
    testImplementation 'org.json:json:20240303'
}